跳至主要内容

RabbitMQ 教程 - "Hello world!"

简介​

信息

先决条件​

本教程假设 RabbitMQ 已安装并在localhost 上的 标准端口（5672）上运行。如果您使用不同的主机、端口或凭据，则连接设置需要调整。

获取帮助​

如果您在完成本教程时遇到问题，您可以通过 GitHub 讨论 或 RabbitMQ 社区 Discord 与我们联系。

RabbitMQ 是一个消息代理：它接收和转发消息。您可以将其视为邮局：当您将要邮寄的邮件投入邮箱时，您可以确信邮递员最终会将邮件送到您的收件人手中。在这个比喻中，RabbitMQ 是一个邮箱、一个邮局和一个邮递员。

RabbitMQ 和邮局之间的主要区别在于它不处理纸张，而是接收、存储和转发数据二进制块——消息。

RabbitMQ 和一般消息传递使用一些行话。

  • 生产仅仅意味着发送。发送消息的程序是生产者

  • 队列是 RabbitMQ 中邮箱的名称。虽然消息会流经 RabbitMQ 和您的应用程序，但它们只能存储在队列中。队列仅受主机内存和磁盘限制的约束，它本质上是一个大型消息缓冲区。

    许多生产者可以发送消息到一个队列，许多消费者可以尝试从一个队列接收数据。

    这就是我们表示队列的方式

  • 消费与接收具有相似的含义。消费者是一个主要等待接收消息的程序

请注意，生产者、消费者和代理不需要驻留在同一台主机上；事实上，在大多数应用程序中，它们并不驻留在同一台主机上。一个应用程序也可以同时是生产者和消费者。

Hello World!​

(使用 amqp Elixir 库)​

在本教程的这一部分中，我们将用 Elixir 编写两个小程序；一个生产者（发送者）发送一条消息，一个消费者（接收者）接收消息并打印出来。这是消息传递的“Hello World”。

在下图中，“P” 是我们的生产者，“C” 是我们的消费者。中间的框是一个队列——RabbitMQ 代表消费者保留的消息缓冲区。

我们的整体设计将如下所示

RabbitMQ 库​

RabbitMQ 支持多种协议。本教程使用 AMQP 0-9-1，它是一种用于消息传递的开放式通用协议。RabbitMQ 在 多种语言 中都有许多客户端。在本教程系列中，我们将使用 amqp。

要安装它，您可以使用 hex 包管理工具。让我们创建一个新项目。

mix new rabbitmq_tutorials
cd rabbitmq_tutorials

现在让我们添加对 amqp 库的依赖项。请修改 mix.exs 文件的 applications 和 deps 部分以匹配以下内容

def application do
  [applications: [:amqp]]
end
defp deps() do
  [
    {:amqp, "~> 3.3"},
  ]
end

mix.exs 的 application 部分将确保在您的项目运行时加载并启动 amqp 依赖项。deps 部分声明您的项目需要哪些外部库。我们现在将使用 mix 来检索和编译 amqp 库。

mix deps.get
mix deps.compile

现在，通过 mix run 执行时，amqp 库将被加载并可用于您的项目。

发送​

我们的第一个程序 send.exs 将向队列发送一条消息。我们需要做的第一件事是与 RabbitMQ 服务器建立连接。

{:ok, connection} = AMQP.Connection.open
{:ok, channel} = AMQP.Channel.open(connection)

我们现在已连接到本地机器上的代理。默认情况下，AMQP.Connection.open 连接到localhost。如果我们要连接到其他机器上的代理，我们只需将其名称或 IP 地址指定为 host: 选项即可。

接下来，在发送之前，我们需要确保接收者队列存在。如果我们向不存在的位置发送消息，RabbitMQ 就会丢弃消息。让我们创建一个队列，消息将被发送到该队列，我们将其命名为hello

AMQP.Queue.declare(channel, "hello")

此时，我们已准备好发送消息。我们的第一条消息将只包含一个字符串Hello World!，我们希望将其发送到我们的hello 队列。

在 RabbitMQ 中，消息永远无法直接发送到队列，它始终需要通过交换器。但让我们不要被细节拖累——您可以在 本教程的第三部分 中阅读更多关于交换器的信息。我们现在只需要知道如何使用由空字符串标识的默认交换器。这个交换器很特别——它允许我们指定消息应该转发的确切队列。队列名称需要在 routing_key 参数中指定

AMQP.Basic.publish(channel, "", "hello", "Hello World!")
IO.puts " [x] Sent 'Hello World!'"

在退出程序之前，我们需要确保网络缓冲区已刷新，并且我们的消息实际上已发送到 RabbitMQ。我们可以通过轻轻地关闭连接来做到这一点。

AMQP.Connection.close(connection)

以下是完整的 send.exs 脚本.

发送不起作用！​

如果这是您第一次使用 RabbitMQ 并且您没有看到“已发送”消息，那么您可能会感到困惑，不知道问题出在哪里。也许代理在启动时没有足够的可用磁盘空间（默认情况下，它需要至少 50 MB 的可用空间），因此拒绝接受消息。检查代理的 日志文件，查看是否记录了 资源警报，并根据需要降低可用磁盘空间阈值。 配置指南 将向您展示如何设置 disk_free_limit。

接收​

这就是我们生产者的全部内容。我们的消费者监听来自 RabbitMQ 的消息，因此与发布一条消息的生产者不同，我们将让消费者持续运行以监听消息并打印出来。

我们的第二个程序 receive.exs 将从队列接收消息并将它们打印到屏幕上。

同样，首先我们需要连接到 RabbitMQ 服务器。负责连接到 Rabbit 的代码与之前相同。

下一步，就像之前一样，是确保队列存在。使用 AMQP.Queue.declare 创建队列是幂等的——我们可以运行该命令任意多次，但只会创建一个。

AMQP.Queue.declare(channel, "hello")

您可能会问为什么我们要再次声明队列——我们已经在之前的代码中声明过了。如果我们确定队列已经存在，我们可以避免这种情况。例如，如果 send.exs 程序已在之前运行过。但我们还不确定先运行哪个程序。在这种情况下，在两个程序中重复声明队列是一个好习惯。

从队列接收消息更加复杂。它通过向 Elixir 进程发送 Elixir 消息来实现。每当客户端库从 RabbitMQ 接收传递时，都会向指定的 Elixir 进程发送一个 {:basic_deliver, payload, metadata} Elixir 消息。然后，我们可以按我们喜欢的任何方式处理有效负载和元数据。在我们的例子中，我们将打印出消息的内容到屏幕上。

defmodule Receive do
  def wait_for_messages do
    receive do
      {:basic_deliver, payload, _meta} ->
        IO.puts " [x] Received #{payload}"
        wait_for_messages()
    end
  end
end

接下来，我们需要告诉 RabbitMQ 这个特定的进程应该从我们的hello 队列接收消息

AMQP.Basic.consume(channel,
                   "hello",
                   nil, # consumer process, defaults to self()
                   no_ack: true)

为了使该命令成功，我们必须确保我们要订阅的队列存在。幸运的是，我们对此很确定——我们在上面创建了一个队列——使用 AMQP.Queue.declare。

列出队列​

您可能希望查看 RabbitMQ 有哪些队列以及队列中有多少条消息。您可以（以特权用户身份）使用 rabbitmqctl 工具来做到这一点

sudo rabbitmqctl list_queues

在 Windows 上，省略 sudo

rabbitmqctl.bat list_queues

no_ack 参数将在 后面 描述。

最后，我们进入一个永不结束的递归，它等待数据并在必要时显示消息。

IO.puts " [*] Waiting for messages. To exit press CTRL+C, CTRL+C"
Receive.wait_for_messages()

组合在一起​

send.exs 的完整代码

{:ok, connection} = AMQP.Connection.open
{:ok, channel} = AMQP.Channel.open(connection)
AMQP.Queue.declare(channel, "hello")
AMQP.Basic.publish(channel, "", "hello", "Hello World!")
IO.puts " [x] Sent 'Hello World!'"
AMQP.Connection.close(connection)

(send.exs 源代码)

完整的 receive.exs 代码

defmodule Receive do
  def wait_for_messages do
    receive do
      {:basic_deliver, payload, _meta} ->
        IO.puts " [x] Received #{payload}"
        wait_for_messages()
    end
  end
end

{:ok, connection} = AMQP.Connection.open
{:ok, channel} = AMQP.Channel.open(connection)
AMQP.Queue.declare(channel, "hello")
AMQP.Basic.consume(channel, "hello", nil, no_ack: true)
IO.puts " [*] Waiting for messages. To exit press CTRL+C, CTRL+C"

Receive.wait_for_messages()

(receive.exs 源代码)

现在，我们可以在终端中尝试我们的程序。首先，让我们启动一个消费者，它将持续运行以等待传递

mix run receive.exs
# => [*] Waiting for messages. To exit press CTRL+C, CTRL+C
# ...
# => [x] Received Hello World!

现在启动生产者。生产者程序将在每次运行后停止

mix run send.exs
# => [x] Sent 'Hello World!'

万岁！我们能够通过 RabbitMQ 发送第一条消息。您可能已经注意到，receive.exs 程序不会退出。它将保持准备状态以接收更多消息，并且可以使用 Ctrl-C、Ctrl-C 来中断。

尝试在新的终端中再次运行 send.exs。

我们已经学会了如何发送和接收来自命名队列的消息。现在是时候继续学习 第 2 部分 并构建一个简单的工作队列了。

© . All rights reserved.